import QtQuick 2.2
import Sailfish.Silica 1.0

// Messaggio dell'ultimo comando, ancorato al bordo inferiore della pagina.
//
// Sta FUORI dal contenuto che scorre: prima il messaggio era la prima riga
// della colonna, quindi premendo un pulsante in fondo alla pagina nasceva
// fuori dallo schermo e non si capiva se il comando fosse partito.
//
// Lo stato sta in ApiClient (api.notice): qui si mostra e basta, cosi' il
// messaggio e' lo stesso su qualsiasi pagina.
Rectangle {
    id: root

    anchors {
        left: parent.left
        right: parent.right
        bottom: parent.bottom
    }
    height: message.height + 2 * Theme.paddingMedium
    color: Qt.rgba(0, 0, 0, 0.78)
    opacity: api.notice.length > 0 ? 1 : 0
    visible: opacity > 0
    z: 100

    Behavior on opacity { NumberAnimation { duration: 200 } }

    Label {
        id: message
        anchors {
            left: parent.left
            right: parent.right
            leftMargin: Theme.horizontalPageMargin
            rightMargin: Theme.horizontalPageMargin
            verticalCenter: parent.verticalCenter
        }
        text: api.notice
        color: api.noticeIsError ? Theme.errorColor : Theme.highlightColor
        font.pixelSize: Theme.fontSizeSmall
        wrapMode: Text.Wrap
    }
}