TEMPLATE = app
TARGET = harbour-aira

CONFIG += sailfishapp
CONFIG += c++11

# Il sailfishapp.prf del kit 5.1 NON aggiunge da solo gli include QtQuick/QtQml
# (sintomo: "QQuickView: No such file or directory").
QT += quick qml
QT += network

SOURCES += \
    src/main.cpp \
    src/settings.cpp \
    src/translator.cpp \
    src/apiclient.cpp \
    src/airajson.cpp

HEADERS += \
    src/settings.h \
    src/translator.h \
    src/apiclient.h \
    src/airajson.h

OTHER_FILES += \
    qml/harbour-aira.qml \
    qml/pages/*.qml \
    qml/cover/*.qml \
    qml/components/*.qml \
    rpm/harbour-aira.spec \
    rpm/harbour-aira.desktop \
    docs/*.md

DISTFILES += $$OTHER_FILES

# Traduzioni: l'inglese e' la lingua sorgente (nessun .qm: Qt lascia le stringhe
# originali quando per il locale non c'e' catalogo = ripiego automatico), mentre
# l'italiano sta in translations/harbour-aira-it.ts.
# Con sailfishapp_i18n qmake compila i .ts in .qm e li installa in
# /usr/share/<TARGET>/translations, che e' dove li cerca src/translator.cpp.
# NIENTE .qm committati: si rigenerano in build.
CONFIG += sailfishapp_i18n

TRANSLATIONS += \
    translations/harbour-aira-it.ts

OTHER_FILES += translations/*.ts

# Icone: struttura standard hicolor, path assoluti (gli install manuali con
# path relativi falliscono quando il tar sorgente e' incompleto).
icons86.path = /usr/share/icons/hicolor/86x86/apps
icons86.files = $$PWD/icons/86x86/harbour-aira.png
icons108.path = /usr/share/icons/hicolor/108x108/apps
icons108.files = $$PWD/icons/108x108/harbour-aira.png
icons128.path = /usr/share/icons/hicolor/128x128/apps
icons128.files = $$PWD/icons/128x128/harbour-aira.png
icons172.path = /usr/share/icons/hicolor/172x172/apps
icons172.files = $$PWD/icons/172x172/harbour-aira.png

INSTALLS += icons86 icons108 icons128 icons172