TEMPLATE = app
TARGET = harbour-calibreweb

CONFIG += sailfishapp
CONFIG += c++11

SOURCES += \
    src/main.cpp \
    src/settings.cpp \
    src/apiclient.cpp \
    src/downloader.cpp \
    src/opdsparser.cpp \
    src/epub.cpp

HEADERS += \
    src/settings.h \
    src/apiclient.h \
    src/downloader.h \
    src/opdsparser.h \
    src/epub.h

LIBS += -lz

OTHER_FILES += \
    qml/harbour-calibreweb.qml \
    qml/pages/*.qml \
    qml/cover/*.qml \
    rpm/harbour-calibreweb.spec \
    rpm/harbour-calibreweb.desktop \
    rpm/harbour-calibreweb.yaml \
    translations/harbour-calibreweb_it.ts

DISTFILES += $$OTHER_FILES

# Translations are NOT handled by the sailfishapp_i18n template on the 5.1 kit
# (the .qm is never generated/installed reliably). The spec builds the .qm
# with lrelease and installs it into /usr/share/translations directly;
# libsailfishapp loads harbour-calibreweb_<locale>.qm automatically.
# Source strings are ENGLISH (default language); harbour-calibreweb_it.ts
# provides the Italian catalogue.

# Icone installate via make install (struttura standard Sailfish: icons/<size>/<name>.png)
icons86.path = /usr/share/icons/hicolor/86x86/apps
icons86.files = $$PWD/icons/86x86/harbour-calibreweb.png
icons108.path = /usr/share/icons/hicolor/108x108/apps
icons108.files = $$PWD/icons/108x108/harbour-calibreweb.png
icons128.path = /usr/share/icons/hicolor/128x128/apps
icons128.files = $$PWD/icons/128x128/harbour-calibreweb.png
icons172.path = /usr/share/icons/hicolor/172x172/apps
icons172.files = $$PWD/icons/172x172/harbour-calibreweb.png
INSTALLS += icons86 icons108 icons128 icons172