import QtQuick 2.0
import Sailfish.Silica 1.0

Page {
    id: page

    SilicaFlickable {
        anchors.fill: parent
        contentHeight: column.height

        Column {
            id: column
            width: parent.width

            PageHeader { title: qsTr("Search") }

            SearchField {
                id: searchField
                width: parent.width
                placeholderText: qsTr("Title or author…")
                EnterKey.enabled: text.length > 0
                EnterKey.onClicked: search()
            }

            Button {
                anchors.horizontalCenter: parent.horizontalCenter
                text: qsTr("Search")
                enabled: searchField.text.length > 0
                onClicked: search()
            }

            Label {
                x: Theme.horizontalPageMargin
                width: parent.width - 2 * Theme.horizontalPageMargin
                text: qsTr("Search uses the server engine (OPDS search).")
                color: Theme.secondaryColor
                font.pixelSize: Theme.fontSizeSmall
                wrapMode: Text.Wrap
            }
        }
    }

    function search() {
        var base = appSettings.baseUrl
        var query = searchField.text.trim()
        if (base.length === 0 || query.length === 0)
            return
        var url = base + "/opds/search?query=" + encodeURIComponent(query)
        pageStack.push(Qt.resolvedUrl("FeedPage.qml"),
                       { feedUrl: url, pageTitle: qsTr("Results: ") + query })
    }
}