Files
harbour-grumpydove/harbour-grumpydove.pro
Carlo Baratto d9aa530ffd Push UnifiedPush come harbour-fmd (0.16.0)
Connector D-Bus org.unifiedpush.Connector.harbour-grumpydove: possiede il nome,
esporta NewEndpoint/Message/Unregistered (Q_CLASSINFO sulla classe, non su un
adaptor: con un adaptor l'interfaccia non viene esportata), si registra col
distributore FogHorn in asincrono e salva token ed endpoint.

Il risveglio si dirama per ambiente (GRUMPYDOVE_PUSH_WAKE=1) prima di creare la
GUI: nessuna finestra, motore in un thread, checkMail, notifica via
org.freedesktop.Notifications, uscita con tetto a 60 s.
preparaPercorsiMotore() sta in un posto solo, usata da app e risveglio.
2026-11-17 12:14:23 +01:00

60 lines
2.0 KiB
Prolog

TEMPLATE = app
TARGET = harbour-grumpydove
CONFIG += sailfishapp
CONFIG += c++11
# QtDBus per il connector UnifiedPush (org.unifiedpush.Connector2)
QT += dbus
# Icone dell'originale compilate nel binario: source QML "qrc:/images/..."
RESOURCES += images.qrc
# Ponte verso il motore di GrumpyDove: libgrumpydove.so e' compilata a parte
# per aarch64 (engine/build_lib.sh) e viaggia nel pacchetto con le librerie
# che Sailfish non ha (libetpan, jansson, runtime Ada).
INCLUDEPATH += $$PWD/engine/include
LIBS += -L$$PWD/engine/prebuilt -l:libgrumpydove.so
# le dipendenze della libreria non sono nel target di build: si risolvono a
# runtime, sul telefono
QMAKE_LFLAGS += -Wl,--allow-shlib-undefined
# dove finira' la libreria nel pacchetto
QMAKE_LFLAGS += -Wl,-rpath,/usr/share/harbour-grumpydove/lib
SOURCES += \
src/main.cpp \
src/enginebridge.cpp \
src/enginecallbacks.cpp \
src/pushservice.cpp \
src/accountsettings.cpp
HEADERS += \
src/enginebridge.h \
src/pushservice.h \
src/accountsettings.h
OTHER_FILES += \
qml/harbour-grumpydove.qml \
qml/pages/*.qml \
qml/cover/*.qml \
qml/js/*.js \
qml/images/*.png \
engine/include/qt_shim.h \
rpm/harbour-grumpydove.spec \
rpm/harbour-grumpydove.desktop
DISTFILES += $$OTHER_FILES
icons86.path = /usr/share/icons/hicolor/86x86/apps
icons86.files = $$PWD/icons/86x86/harbour-grumpydove.png
icons108.path = /usr/share/icons/hicolor/108x108/apps
icons108.files = $$PWD/icons/108x108/harbour-grumpydove.png
icons128.path = /usr/share/icons/hicolor/128x128/apps
icons128.files = $$PWD/icons/128x128/harbour-grumpydove.png
icons172.path = /usr/share/icons/hicolor/172x172/apps
icons172.files = $$PWD/icons/172x172/harbour-grumpydove.png
INSTALLS += icons86 icons108 icons128 icons172
# Il motore e le librerie che Sailfish non ha: elenco esplicito generato da
# packaging/bundle_libs.py (un glob verrebbe espanso quando i file non ci
# sono ancora). Il file si rigenera dopo ogni bundling.
include(engine/prebuilt/files.pri)