TEMPLATE = app
TARGET = harbour-henflow

CONFIG += sailfishapp
CONFIG += c++11

# Il sailfishapp.prf del kit 5.1 NON aggiunge da solo gli include QtQuick/QtQml
# (sintomo: "QQuickView: No such file or directory").
QT += quick qml

SOURCES += \
    src/main.cpp \
    src/settings.cpp

HEADERS += \
    src/settings.h

OTHER_FILES += \
    qml/harbour-henflow.qml \
    qml/pages/*.qml \
    qml/cover/*.qml \
    qml/js/henflow.js \
    qml/js/i18n.js \
    qml/js/catalog.js \
    rpm/harbour-henflow.spec \
    rpm/harbour-henflow.desktop \
    translations/harbour-henflow.ts \
    translations/harbour-henflow_it.ts

DISTFILES += $$OTHER_FILES

# Le traduzioni NON passano dal template sailfishapp_i18n (sul kit 5.1 il .qm
# non viene generato/installato in modo affidabile): lo spec compila il catalogo
# con lrelease e lo installa nel datadir dell'app, main.cpp lo carica da li'.
# Le stringhe sorgente sono INGLESI (lingua di default di Sailfish).

# Icone: struttura standard hicolor, path assoluti (gli install manuali con
# path relativi falliscono se il tar sorgente e' incompleto).
icons86.path = /usr/share/icons/hicolor/86x86/apps
icons86.files = $$PWD/icons/86x86/harbour-henflow.png
icons108.path = /usr/share/icons/hicolor/108x108/apps
icons108.files = $$PWD/icons/108x108/harbour-henflow.png
icons128.path = /usr/share/icons/hicolor/128x128/apps
icons128.files = $$PWD/icons/128x128/harbour-henflow.png
icons172.path = /usr/share/icons/hicolor/172x172/apps
icons172.files = $$PWD/icons/172x172/harbour-henflow.png

INSTALLS += icons86 icons108 icons128 icons172

# Foto delle razze nel datadir dell'app: il catalogo (qml/js/catalog.js) le
# riferisce con path assoluto, perche' QML non vede la cartella sorgente una
# volta installata l'app. Nota: nel repo la foto 'olive' era un WEBP travestito
# da .jpg (Qt 5.6 su Sailfish non ha il plugin webp) -> riconvertita in JPEG.
breeds.path = /usr/share/harbour-henflow/breeds
breeds.files = $$PWD/assets/breeds/*.jpg

INSTALLS += breeds